#! /bin/tcsh
set F=1

set T=Test$F
set P=drawphase$F

if ($# != 1) then
	echo "$0:t : zip file expected"
	exit
endif
if ( ! -f "$1" ) then
	echo "$0:t : $1 should be a zip file"
	exit
endif
if ( -e $T ) then
	rm -rf $T
endif
mkdir $T
cp "$1" $T
cd $T
jar xf "$1:t"
rm -f *.class *.jj *.svg *.svgd $P.java >& /dev/null
if ( ! -f $P.jjt ) then
	echo "$0:t : expected file $P.jjt"
	exit
endif
echo "# JJTree called for $P.jjt"
jjtree $P.jjt
if ( ! -f $P.jj ) then
	echo "$0:t : expected file $P.jj to be created"
	exit
endif
echo "# JavaCC called for $P.jj"
javacc $P.jj
if ( ! -f $P.java ) then
	echo "$0:t : expected file $P.java to be created"
	exit
endif
echo "# JavaC called for $P.java"
javac $P.java
if ( ! -f $P.class ) then
	echo "$0:t : expected file $P.class to be created"
	exit
endif
echo "# Java called for $P for test cases"
java $P < ../Ref/LineTest.svgd > LineTest.svg
java $P < ../Ref/JuggleBW.svgd > JuggleBW.svg
java $P < ../Ref/TestBW.svgd > TestBW.svg
echo "# Test cases processed : See $P.html for results"
